rt-thread-official/bsp/stm32f4xx-HAL/drivers/SConscript

Import('RTT_ROOT')
Import('rtconfig')
from building import *

cwd = os.path.join(str(Dir('#')), 'drivers')

# add the general drivers.
src = Split("""
board.c
stm32f4xx_it.c
""")

if GetDepend(['RT_USING_PIN']):
    src += ['drv_gpio.c']

if GetDepend(['RT_USING_SERIAL']):
    src += ['drv_usart.c']

if GetDepend(['RT_USING_SPI']):
    src += ['drv_spi.c']

if GetDepend(['RT_USING_W25QXX']) or GetDepend(['RT_USING_SFUD']):
    src += ['drv_spiflash.c']

if GetDepend(['RT_USING_WDT']):
    src += ['drv_iwg.c']

if GetDepend(['RT_USING_USB_DEVICE']):
    src += ['drv_usbd.c']

if GetDepend(['RT_USING_RTC']):
    src += ['drv_rtc.c']

if GetDepend(['RT_USING_USB_HOST']):
    src += ['drv_usbh.c']

if GetDepend(['RT_USING_I2C']):
    src += ['drv_i2c.c']

if GetDepend(['RT_USING_CAN']):
    src += ['drv_can.c']

if GetDepend(['RT_USING_PWM']):
    src += ['drv_pwm.c']

CPPPATH = [cwd]

group = DefineGroup('Drivers', src, depend = [''], CPPPATH = CPPPATH)

Return('group')