mirror of
git://sourceware.org/git/newlib-cygwin.git
synced 2025-01-18 04:19:21 +08:00
ef44da427f
* libc/machine/i386/i386mach.h: added SOTYPE_FUNCTION to set type
of global entry points if _I386MACH_NEED_SOTYPE_FUNCTION is defined;
Added __CLI and __STI macros (controlled via
_I386MACH_ALLOW_HW_INTERRUPTS macro).
* libc/machine/i386/f_atan2.S libc/machine/i386/f_atan2f.S
libc/machine/i386/f_frexp.S libc/machine/i386/f_frexpf.S
libc/machine/i386/f_ldexp.S libc/machine/i386/f_ldexpf.S
libc/machine/i386/f_log.S libc/machine/i386/f_log10.S
libc/machine/i386/f_log10f.S libc/machine/i386/f_logf.S
libc/machine/i386/f_tan.S libc/machine/i386/f_tanf.S
libc/machine/i386/memchr.S libc/machine/i386/memcmp.S
libc/machine/i386/memcpy.S libc/machine/i386/memmove.S
libc/machine/i386/memset.S libc/machine/i386/setjmp.S
libc/machine/i386/strchr.S libc/machine/i386/strlen.S:
(that's libc/machine/i386/*.S) added SOTYPE_FUNCTION(symbol)
for all global entry points.
* libc/machine/i386/setjmp.S: removed code replicated in
libc/machine/i386/i386mach.h and included i386mach.h instead;
Use __CLI and __STI instead of cli and sti.
77 lines
1.3 KiB
ArmAsm
77 lines
1.3 KiB
ArmAsm
/*
|
|
* ====================================================
|
|
* Copyright (C) 1998 by Cygnus Solutions. All rights reserved.
|
|
*
|
|
* Permission to use, copy, modify, and distribute this
|
|
* software is freely granted, provided that this notice
|
|
* is preserved.
|
|
* ====================================================
|
|
*/
|
|
|
|
#include "i386mach.h"
|
|
|
|
.global SYM (memcmp)
|
|
SOTYPE_FUNCTION(memcmp)
|
|
|
|
SYM (memcmp):
|
|
|
|
pushl ebp
|
|
movl esp,ebp
|
|
subl $16,esp
|
|
pushl ebx
|
|
pushl edi
|
|
pushl esi
|
|
movl 8(ebp),edi
|
|
movl 12(ebp),esi
|
|
movl 16(ebp),ecx
|
|
cld
|
|
|
|
/* check if length is zero in which case just return 0 */
|
|
|
|
xorl eax,eax
|
|
testl ecx,ecx
|
|
jz L4
|
|
|
|
#ifndef __OPTIMIZE_SIZE__
|
|
|
|
/* if aligned on long boundary, compare doublewords at a time first */
|
|
|
|
movl edi,eax
|
|
orl esi,eax
|
|
testb $3,al
|
|
jne BYTECMP
|
|
movl ecx,ebx
|
|
shrl $2,ecx /* calculate number of long words to compare */
|
|
repz
|
|
cmpsl
|
|
jz L5
|
|
subl $4,esi
|
|
subl $4,edi
|
|
movl $4,ecx
|
|
jmp BYTECMP
|
|
L5:
|
|
andl $3,ebx /* calculate number of remaining bytes */
|
|
movl ebx,ecx
|
|
|
|
#endif /* not __OPTIMIZE_SIZE__ */
|
|
|
|
BYTECMP: /* compare any unaligned bytes or remainder bytes */
|
|
repz
|
|
cmpsb
|
|
|
|
/* set output to be < 0 if less than, 0 if equal, or > 0 if greater than */
|
|
L3:
|
|
xorl edx,edx
|
|
movb -1(esi),dl
|
|
xorl eax,eax
|
|
movb -1(edi),al
|
|
subl edx,eax
|
|
|
|
L4:
|
|
leal -28(ebp),esp
|
|
popl esi
|
|
popl edi
|
|
popl ebx
|
|
leave
|
|
ret
|