mirror of
git://sourceware.org/git/newlib-cygwin.git
synced 2025-02-24 09:39:33 +08:00
d36ae2cec9
* m68k/Makefile.in: Adjust Coldfire rules. (BDM_CRT0, BDM_BSP, BDM_OBJS, BDM_ISRS): Rename to ... (CF_CRT0, CF_BSP, CF_OBJS, CF_ISRS): ... here. Adjust. (BDM_OTHER_OBJS): Remove. (BDM_SYSOBJS): Rename to ... (UNHOSTED_OBJS): ... here. Adjust. (UNHOSTED_BSP, HOSTED_OBJS, HOSTED_BSP): New. (CF_HOSTED_SCRIPTS): New. (CF_SCRIPTS, CF_SOURCES): Adjust. * m68k/cf.sc: Add IO library variable. * m68k/bdm-crt0.S, m68k/bdm-crt1.c, m68k/bdm-isrs.c, m68k/bdm-sbrk.c, m68k/bdm-semihost.S: Rename to ... * m68k/cf-crt0.S, m68k/cf-crt1.c, m68k/cf-isrs.c, m68k/cf-sbrk.c, m68k/cf-hosted.S: ... here. * m68k/cf-exit.c: New. * m68k/bdm-gdb.h, m68k/bdm-semihost.h: Merge into ... * m68k/io.h: ... here. Add unhosted support. Adjust conversion function names. * m68k/bdm-gdb.c: Rename to ... * m68k/io-gdb.c: ... here. Adjust names of conversion functions. * m68k/bdm-close.c, m68k/bdm-exit.c, m68k/bdm-fstat.c, m68k/bdm-gettimeofday.c, m68k/bdm-isatty.c, m68k/bdm-lseek.c, m68k/bdm-open.c, m68k/bdm-read.c, m68k/bdm-rename.c, m68k/bdm-stat.c, m68k/bdm-system.c, m68k/bdm-time.c, m68k/bdm-unlink.c, m68k/bdm-write.c: Rename to ... * m68k/io-close.c, m68k/io-exit.c, m68k/io-fstat.c, m68k/io-gettimeofday.c, m68k/io-isatty.c, m68k/io-lseek.c, m68k/io-open.c, m68k/io-read.c, m68k/io-rename.c, m68k/io-stat.c, m68k/io-system.c, m68k/io-time.c, m68k/io-unlink.c, m68k/io-write.c: ... here. Include io.h. Adjust for hosted & unhosted libraries. Adjust names of gdb conversion functions.
112 lines
2.1 KiB
Scala
112 lines
2.1 KiB
Scala
# a linker script template.
|
|
# RAM - start of board's ram
|
|
# RAM_SIZE - size of board's ram
|
|
# ROM - start of board's rom
|
|
# ROM_SIZE - size of board's rom
|
|
# IO - io library name
|
|
|
|
test -z "${ROM:+1}" && NOROM=1
|
|
|
|
cat <<EOF
|
|
STARTUP(cf-crt0.o)
|
|
OUTPUT_ARCH(m68k)
|
|
ENTRY(__start)
|
|
SEARCH_DIR(.)
|
|
GROUP(-lc -l${IO} -lcf)
|
|
__DYNAMIC = 0;
|
|
|
|
MEMORY
|
|
{
|
|
${ROM:+rom (rx) : ORIGIN = ${ROM}, LENGTH = ${ROM_SIZE}}
|
|
ram (rwx) : ORIGIN = ${RAM}, LENGTH = ${RAM_SIZE}
|
|
}
|
|
|
|
/* Place the stack at the end of memory, unless specified otherwise. */
|
|
PROVIDE (__stack = ${RAM} + ${RAM_SIZE});
|
|
|
|
SECTIONS
|
|
{
|
|
.text :
|
|
{
|
|
CREATE_OBJECT_SYMBOLS
|
|
cf-crt0.o(.text)
|
|
*(.text .text.*)
|
|
|
|
. = ALIGN(0x4);
|
|
/* These are for running static constructors and destructors under ELF. */
|
|
KEEP (*crtbegin.o(.ctors))
|
|
KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
|
|
KEEP (*(SORT(.ctors.*)))
|
|
KEEP (*crtend.o(.ctors))
|
|
KEEP (*crtbegin.o(.dtors))
|
|
KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
|
|
KEEP (*(SORT(.dtors.*)))
|
|
KEEP (*crtend.o(.dtors))
|
|
|
|
. = ALIGN(0x4);
|
|
KEEP (*crtbegin.o(.jcr))
|
|
KEEP (*(EXCLUDE_FILE (*crtend.o) .jcr))
|
|
KEEP (*crtend.o(.jcr))
|
|
|
|
*(.rodata .rodata.*)
|
|
|
|
. = ALIGN(0x4);
|
|
*(.gcc_except_table)
|
|
|
|
. = ALIGN(0x4);
|
|
*(.eh_frame)
|
|
|
|
. = ALIGN(0x4);
|
|
__INIT_SECTION__ = . ;
|
|
LONG (0x4e560000) /* linkw %fp,#0 */
|
|
*(.init)
|
|
SHORT (0x4e5e) /* unlk %fp */
|
|
SHORT (0x4e75) /* rts */
|
|
|
|
. = ALIGN(0x4);
|
|
__FINI_SECTION__ = . ;
|
|
LONG (0x4e560000) /* linkw %fp,#0 */
|
|
*(.fini)
|
|
SHORT (0x4e5e) /* unlk %fp */
|
|
SHORT (0x4e75) /* rts */
|
|
|
|
*(.lit)
|
|
|
|
. = ALIGN(4);
|
|
_etext = .;
|
|
} >${ROM:+rom}${NOROM:+ram}
|
|
|
|
.data :
|
|
{
|
|
__data_load = LOADADDR (.data);
|
|
__data_start = .;
|
|
*(.got.plt) *(.got)
|
|
*(.shdata)
|
|
*(.data .data.*)
|
|
. = ALIGN (4);
|
|
_edata = .;
|
|
} >ram ${ROM:+AT>rom}
|
|
|
|
.bss :
|
|
{
|
|
__bss_start = . ;
|
|
*(.shbss)
|
|
*(.bss .bss.*)
|
|
*(COMMON)
|
|
. = ALIGN (8);
|
|
_end = .;
|
|
__end = _end;
|
|
} >ram ${ROM:+AT>rom}
|
|
|
|
.stab 0 (NOLOAD) :
|
|
{
|
|
*(.stab)
|
|
}
|
|
|
|
.stabstr 0 (NOLOAD) :
|
|
{
|
|
*(.stabstr)
|
|
}
|
|
}
|
|
EOF
|