mirror of
git://sourceware.org/git/newlib-cygwin.git
synced 2025-02-23 09:09:35 +08:00
e7cd1e99ea
* config.sub: Recognize fido and fido-*. libgloss/ * configure.in: Recognize fido-*-*. * configure: Regenerate. * m68k/Makefile.in (CF_ISRS): Use addprefix. (FIDO_CRT0, FIDO_BSP, FIDO_OBJS, FIDO_HANDLERS, FIDO_UNHOSTED_SCRIPTS, FIDO_HOSTED_SCRIPTS, FIDO_SCRIPTS, FIDO_SOURCES, all_fido, fido-%-crt0.o, fido-rom.ld, fido-rom-hosted.ld, fido-sram.ld, fido-sram-hosted.ld, fido-sdram.ld, fido-sdram-hosted.ld, fido-redboot.ld, install_fido): New. * m68k/asm.h (mbb): New. * m68k/configure.in (DO): Check for __mfido__. * m68k/configure: Regenerate. * m68k/fido-_exit.c, m68k/fido-crt0.S, m68k/fido-handler.c, m68k/fido-hosted.S, m68k/fido-sbrk.c, m68k/fido.h, m68k/fido.sc, m68k/fido_profiling.h: New. newlib/ * configure.host: Recognize fido.
121 lines
3.3 KiB
Plaintext
121 lines
3.3 KiB
Plaintext
# Copyright (c) 1995, 1996 Cygnus Support
|
|
#
|
|
# The authors hereby grant permission to use, copy, modify, distribute,
|
|
# and license this software and its documentation for any purpose, provided
|
|
# that existing copyright notices are retained in all copies and that this
|
|
# notice is included verbatim in any distributions. No written agreement,
|
|
# license, or royalty fee is required for any of the authorized uses.
|
|
# Modifications to this software may be copyrighted by their authors
|
|
# and need not follow the licensing terms described here, provided that
|
|
# the new terms are clearly indicated on the first page of each file where
|
|
# they apply.
|
|
#
|
|
# process this file with autoconf to produce a configure script.
|
|
AC_PREREQ(2.5)dnl
|
|
AC_INIT(crt0.S)
|
|
|
|
if test "${enable_shared}" = "yes" ; then
|
|
echo "Shared libraries not supported for cross compiling, ignored"
|
|
fi
|
|
|
|
if test "$srcdir" = "." ; then
|
|
if test "${with_target_subdir}" != "." ; then
|
|
libgloss_topdir="${with_multisrctop}../../.."
|
|
else
|
|
libgloss_topdir="${with_multisrctop}../.."
|
|
fi
|
|
else
|
|
libgloss_topdir="${srcdir}/../.."
|
|
fi
|
|
|
|
AC_CONFIG_AUX_DIR($libgloss_topdir)
|
|
AC_CANONICAL_SYSTEM
|
|
AC_ARG_PROGRAM
|
|
|
|
AC_PROG_INSTALL
|
|
|
|
# FIXME: We temporarily define our own version of AC_PROG_CC. This is
|
|
# copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS. We
|
|
# are probably using a cross compiler, which will not be able to fully
|
|
# link an executable. This should really be fixed in autoconf
|
|
# itself.
|
|
|
|
AC_DEFUN(LIB_AC_PROG_CC,
|
|
[AC_BEFORE([$0], [AC_PROG_CPP])dnl
|
|
AC_CHECK_PROG(CC, gcc, gcc)
|
|
if test -z "$CC"; then
|
|
AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
|
|
test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
|
|
fi
|
|
|
|
AC_PROG_CC_GNU
|
|
|
|
if test $ac_cv_prog_gcc = yes; then
|
|
GCC=yes
|
|
dnl Check whether -g works, even if CFLAGS is set, in case the package
|
|
dnl plays around with CFLAGS (such as to build both debugging and
|
|
dnl normal versions of a library), tasteless as that idea is.
|
|
ac_test_CFLAGS="${CFLAGS+set}"
|
|
ac_save_CFLAGS="$CFLAGS"
|
|
CFLAGS=
|
|
AC_PROG_CC_G
|
|
if test "$ac_test_CFLAGS" = set; then
|
|
CFLAGS="$ac_save_CFLAGS"
|
|
elif test $ac_cv_prog_cc_g = yes; then
|
|
CFLAGS="-g -O2"
|
|
else
|
|
CFLAGS="-O2"
|
|
fi
|
|
else
|
|
GCC=
|
|
test "${CFLAGS+set}" = set || CFLAGS="-g"
|
|
fi
|
|
])
|
|
|
|
LIB_AC_PROG_CC
|
|
|
|
AS=${AS-as}
|
|
AC_SUBST(AS)
|
|
AR=${AR-ar}
|
|
AC_SUBST(AR)
|
|
LD=${LD-ld}
|
|
AC_SUBST(LD)
|
|
AC_PROG_RANLIB
|
|
|
|
AC_MSG_CHECKING([target cpu family])
|
|
DO=m68k
|
|
AC_TRY_COMPILE(,[#ifndef __mcoldfire__
|
|
#error we are not coldfire
|
|
#endif],
|
|
DO="cf")
|
|
AC_TRY_COMPILE(,[#ifndef __mfido__
|
|
#error we are not fido
|
|
#endif],
|
|
DO="fido")
|
|
AC_MSG_RESULT($DO)
|
|
AC_SUBST(DO)
|
|
|
|
host_makefile_frag=${srcdir}/../config/default.mh
|
|
target_makefile_frag=${srcdir}/../config/default.mt
|
|
|
|
dnl We have to assign the same value to other variables because autoconf
|
|
dnl doesn't provide a mechanism to substitute a replacement keyword with
|
|
dnl arbitrary data or pathnames.
|
|
dnl
|
|
host_makefile_frag_path=$host_makefile_frag
|
|
AC_SUBST(host_makefile_frag_path)
|
|
AC_SUBST_FILE(host_makefile_frag)
|
|
target_makefile_frag_path=$target_makefile_frag
|
|
AC_SUBST(target_makefile_frag_path)
|
|
AC_SUBST_FILE(target_makefile_frag)
|
|
|
|
AC_OUTPUT(Makefile,
|
|
. ${libgloss_topdir}/config-ml.in,
|
|
srcdir=${srcdir}
|
|
target=${target}
|
|
ac_configure_args="${ac_configure_args} --enable-multilib"
|
|
CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
|
|
libgloss_topdir=${libgloss_topdir}
|
|
)
|
|
|