mirror of
git://sourceware.org/git/newlib-cygwin.git
synced 2025-01-15 11:00:04 +08:00
ef44da427f
* libc/machine/i386/i386mach.h: added SOTYPE_FUNCTION to set type
of global entry points if _I386MACH_NEED_SOTYPE_FUNCTION is defined;
Added __CLI and __STI macros (controlled via
_I386MACH_ALLOW_HW_INTERRUPTS macro).
* libc/machine/i386/f_atan2.S libc/machine/i386/f_atan2f.S
libc/machine/i386/f_frexp.S libc/machine/i386/f_frexpf.S
libc/machine/i386/f_ldexp.S libc/machine/i386/f_ldexpf.S
libc/machine/i386/f_log.S libc/machine/i386/f_log10.S
libc/machine/i386/f_log10f.S libc/machine/i386/f_logf.S
libc/machine/i386/f_tan.S libc/machine/i386/f_tanf.S
libc/machine/i386/memchr.S libc/machine/i386/memcmp.S
libc/machine/i386/memcpy.S libc/machine/i386/memmove.S
libc/machine/i386/memset.S libc/machine/i386/setjmp.S
libc/machine/i386/strchr.S libc/machine/i386/strlen.S:
(that's libc/machine/i386/*.S) added SOTYPE_FUNCTION(symbol)
for all global entry points.
* libc/machine/i386/setjmp.S: removed code replicated in
libc/machine/i386/i386mach.h and included i386mach.h instead;
Use __CLI and __STI instead of cli and sti.
86 lines
1.4 KiB
ArmAsm
86 lines
1.4 KiB
ArmAsm
/*
|
|
* ====================================================
|
|
* Copyright (C) 1998 by Cygnus Solutions. All rights reserved.
|
|
*
|
|
* Permission to use, copy, modify, and distribute this
|
|
* software is freely granted, provided that this notice
|
|
* is preserved.
|
|
* ====================================================
|
|
*/
|
|
|
|
#include "i386mach.h"
|
|
|
|
.global SYM (strchr)
|
|
SOTYPE_FUNCTION(strchr)
|
|
|
|
SYM (strchr):
|
|
|
|
pushl ebp
|
|
movl esp,ebp
|
|
pushl edi
|
|
pushl ebx
|
|
xorl ebx,ebx
|
|
movl 8(ebp),edi
|
|
movb 12(ebp),bl
|
|
|
|
#ifndef __OPTIMIZE_SIZE__
|
|
/* check if string is aligned, if not do check one byte at a time */
|
|
test $3,edi
|
|
jne L9
|
|
|
|
/* create 4 byte mask which is just the desired byte repeated 4 times */
|
|
movl ebx,ecx
|
|
sall $8,ebx
|
|
subl $4,edi
|
|
orl ecx,ebx
|
|
movl ebx,edx
|
|
sall $16,ebx
|
|
orl edx,ebx
|
|
|
|
/* loop performing 4 byte mask checking for 0 byte or desired byte */
|
|
.p2align 4,,7
|
|
L10:
|
|
addl $4,edi
|
|
movl (edi),ecx
|
|
leal -16843009(ecx),edx
|
|
movl ecx,eax
|
|
notl eax
|
|
andl eax,edx
|
|
testl $-2139062144,edx
|
|
jne L9
|
|
|
|
movl ebx,eax
|
|
xorl ecx,eax
|
|
leal -16843009(eax),edx
|
|
notl eax
|
|
andl eax,edx
|
|
testl $-2139062144,edx
|
|
je L10
|
|
#endif /* not __OPTIMIZE_SIZE__ */
|
|
|
|
/* loop while (*s && *s++ != c) */
|
|
L9:
|
|
leal -1(edi),eax
|
|
.p2align 4,,7
|
|
L15:
|
|
incl eax
|
|
movb (eax),dl
|
|
testb dl,dl
|
|
je L14
|
|
cmpb bl,dl
|
|
jne L15
|
|
|
|
L14:
|
|
/* if (*s == c) return address otherwise return NULL */
|
|
cmpb bl,(eax)
|
|
je L19
|
|
xorl eax,eax
|
|
|
|
L19:
|
|
leal -8(ebp),esp
|
|
popl ebx
|
|
popl edi
|
|
leave
|
|
ret
|
|
|