mirror of
git://sourceware.org/git/newlib-cygwin.git
synced 2025-01-16 19:40:07 +08:00
5d3ad3b123
Intel MCU System V ABI are incompartible with i386 System V ABI:
o Minimum instruction set is Intel Pentium ISA minus x87 instructions
o No x87 or vector registers
o First three args are passed in %eax, %edx and %ecx
o Full specification available here:
https://github.com/hjl-tools/x86-psABI/wiki/iamcu-psABI-0.7.pdf
newlib/
* configure.host: Add new ix86-*-elfiamcu target
newlib/libc/include/
* setjmp.h: Change _JBLEN for Intel MCU target
newlib/libc/machine/i386/
* memchr.S: (memchr) Target-specific size-optimized version
* memcmp.S: (memcmp) Likewise
* memcpy.S: (memcpy) Likewise
* memmove.S: (memmove) Likewise
* memset.S: (memset) Likewise
* setjmp.S: (setjmp) Likewise
* strchr.S: (strchr) Likewise
* strlen.S: (strlen) Likewise
newlib/libc/stdlib/
* srtold.c: (__flt_rounds) Disable for Intel MCU
110 lines
1.5 KiB
ArmAsm
110 lines
1.5 KiB
ArmAsm
/*
|
|
* ====================================================
|
|
* Copyright (C) 1998, 2002, 2008 by Red Hat Inc. All rights reserved.
|
|
*
|
|
* Permission to use, copy, modify, and distribute this
|
|
* software is freely granted, provided that this notice
|
|
* is preserved.
|
|
* ====================================================
|
|
*/
|
|
|
|
#include "i386mach.h"
|
|
|
|
.global SYM (memset)
|
|
SOTYPE_FUNCTION(memset)
|
|
|
|
SYM (memset):
|
|
|
|
#ifdef __iamcu__
|
|
pushl edi
|
|
movl eax,edi
|
|
movzbl dl,eax
|
|
mov edi,edx
|
|
rep stosb
|
|
mov edx,eax
|
|
popl edi
|
|
#else
|
|
pushl ebp
|
|
movl esp,ebp
|
|
pushl edi
|
|
movl 8(ebp),edi
|
|
movzbl 12(ebp),eax
|
|
movl 16(ebp),ecx
|
|
cld
|
|
|
|
#ifndef __OPTIMIZE_SIZE__
|
|
/* Less than 16 bytes won't benefit from the 'rep stosl' loop. */
|
|
cmpl $16,ecx
|
|
jbe .L19
|
|
testl $7,edi
|
|
je .L10
|
|
|
|
/* It turns out that 8-byte aligned 'rep stosl' outperforms
|
|
4-byte aligned on some x86 platforms. */
|
|
movb al,(edi)
|
|
incl edi
|
|
decl ecx
|
|
testl $7,edi
|
|
je .L10
|
|
|
|
movb al,(edi)
|
|
incl edi
|
|
decl ecx
|
|
testl $7,edi
|
|
je .L10
|
|
|
|
movb al,(edi)
|
|
incl edi
|
|
decl ecx
|
|
testl $7,edi
|
|
je .L10
|
|
|
|
movb al,(edi)
|
|
incl edi
|
|
decl ecx
|
|
testl $7,edi
|
|
je .L10
|
|
|
|
movb al,(edi)
|
|
incl edi
|
|
decl ecx
|
|
testl $7,edi
|
|
je .L10
|
|
|
|
movb al,(edi)
|
|
incl edi
|
|
decl ecx
|
|
testl $7,edi
|
|
je .L10
|
|
|
|
movb al,(edi)
|
|
incl edi
|
|
decl ecx
|
|
|
|
/* At this point, ecx>8 and edi%8==0. */
|
|
.L10:
|
|
movb al,ah
|
|
movl eax,edx
|
|
sall $16,edx
|
|
orl edx,eax
|
|
|
|
movl ecx,edx
|
|
shrl $2,ecx
|
|
andl $3,edx
|
|
rep
|
|
stosl
|
|
movl edx,ecx
|
|
#endif /* not __OPTIMIZE_SIZE__ */
|
|
|
|
.L19:
|
|
rep
|
|
stosb
|
|
|
|
movl 8(ebp),eax
|
|
|
|
leal -4(ebp),esp
|
|
popl edi
|
|
leave
|
|
#endif
|
|
ret
|